home *** CD-ROM | disk | FTP | other *** search
/ The Arsenal Files 8 / The Arsenal Files Collection #8 (Arsenal Computer) (1996).ISO / g_quake / doomguns.zip / WEAPONS.QC < prev   
Text File  |  1996-10-14  |  25KB  |  1,222 lines
  1. /*
  2. */
  3. void (entity targ, entity inflictor, entity attacker, float damage) T_Damage;
  4. void () player_run;
  5. void(entity bomb, entity attacker, float rad, entity ignore) T_RadiusDamage;
  6. void(vector org, vector vel, float damage) SpawnBlood;
  7. void() SuperDamageSound;
  8.  
  9.  
  10. // called by worldspawn
  11. void() W_Precache =
  12. {
  13.     precache_sound ("weapons/r_exp3.wav");    // new rocket explosion
  14.     precache_sound ("weapons/rocket1i.wav");    // spike gun
  15.     precache_sound ("weapons/sgun1.wav");
  16.     precache_sound ("weapons/guncock.wav");    // player shotgun
  17.     precache_sound ("weapons/ric1.wav");    // ricochet (used in c code)
  18.     precache_sound ("weapons/ric2.wav");    // ricochet (used in c code)
  19.     precache_sound ("weapons/ric3.wav");    // ricochet (used in c code)
  20.     precache_sound ("weapons/spike2.wav");    // super spikes
  21.     precache_sound ("weapons/tink1.wav");    // spikes tink (used in c code)
  22.     precache_sound ("weapons/grenade.wav");    // grenade launcher
  23.     precache_sound ("weapons/bounce.wav");        // grenade bounce
  24.     precache_sound ("weapons/shotgn2.wav");    // super shotgun
  25. };
  26.  
  27. float() crandom =
  28. {
  29.     return 2*(random() - 0.5);
  30. };
  31.  
  32. /*
  33. ================
  34. W_FireAxe
  35. ================
  36. */
  37. void() W_FireAxe =
  38. {
  39.     local    vector    source;
  40.     local    vector    org;
  41.  
  42.     source = self.origin + '0 0 16';
  43.     traceline (source, source + v_forward*64, FALSE, self);
  44.     if (trace_fraction == 1.0)
  45.         return;
  46.     
  47.     org = trace_endpos - v_forward*4;
  48.  
  49.     if (trace_ent.takedamage)
  50.     {
  51.         trace_ent.axhitme = 1;
  52.         SpawnBlood (org, '0 0 0', 20);
  53.         T_Damage (trace_ent, self, self, 40 + 80*random());
  54.     }
  55.     else
  56.     {    // hit wall
  57.         sound (self, CHAN_WEAPON, "player/axhit2.wav", 1, ATTN_NORM);
  58.         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  59.         WriteByte (MSG_BROADCAST, TE_GUNSHOT);
  60.         WriteCoord (MSG_BROADCAST, org_x);
  61.         WriteCoord (MSG_BROADCAST, org_y);
  62.         WriteCoord (MSG_BROADCAST, org_z);
  63.     }
  64. };
  65.  
  66.  
  67. //============================================================================
  68.  
  69.  
  70. vector() wall_velocity =
  71. {
  72.     local vector    vel;
  73.     
  74.     vel = normalize (self.velocity);
  75.     vel = normalize(vel + v_up*(random()- 0.5) + v_right*(random()- 0.5));
  76.     vel = vel + 2*trace_plane_normal;
  77.     vel = vel * 200;
  78.     
  79.     return vel;
  80. };
  81.  
  82.  
  83. /*
  84. ================
  85. SpawnMeatSpray
  86. ================
  87. */
  88. void(vector org, vector vel) SpawnMeatSpray =
  89. {
  90.     local    entity missile, mpuff;
  91.     local    vector    org;
  92.  
  93.     missile = spawn ();
  94.     missile.owner = self;
  95.     missile.movetype = MOVETYPE_BOUNCE;
  96.     missile.solid = SOLID_NOT;
  97.  
  98.     makevectors (self.angles);
  99.  
  100.     missile.velocity = vel;
  101.     missile.velocity_z = missile.velocity_z + 250 + 50*random();
  102.  
  103.     missile.avelocity = '3000 1000 2000';
  104.     
  105. // set missile duration
  106.     missile.nextthink = time + 1;
  107.     missile.think = SUB_Remove;
  108.  
  109.     setmodel (missile, "progs/zom_gib.mdl");
  110.     setsize (missile, '0 0 0', '0 0 0');        
  111.     setorigin (missile, org);
  112. };
  113.  
  114. /*
  115. ================
  116. SpawnBlood
  117. ================
  118. */
  119. void(vector org, vector vel, float damage) SpawnBlood =
  120. {
  121.     particle (org, vel*0.1, 73, damage*2);
  122. };
  123.  
  124. /*
  125. ================
  126. spawn_touchblood
  127. ================
  128. */
  129. void(float damage) spawn_touchblood =
  130. {
  131.     local vector    vel;
  132.  
  133.     vel = wall_velocity () * 0.2;
  134.     SpawnBlood (self.origin + vel*0.01, vel, damage);
  135. };
  136.  
  137.  
  138. /*
  139. ================
  140. SpawnChunk
  141. ================
  142. */
  143. void(vector org, vector vel) SpawnChunk =
  144. {
  145.     particle (org, vel*0.02, 0, 10);
  146. };
  147.  
  148. /*
  149. ==============================================================================
  150.  
  151. MULTI-DAMAGE
  152.  
  153. Collects multiple small damages into a single damage
  154.  
  155. ==============================================================================
  156. */
  157.  
  158. entity    multi_ent;
  159. float    multi_damage;
  160.  
  161. void() ClearMultiDamage =
  162. {
  163.     multi_ent = world;
  164.     multi_damage = 0;
  165. };
  166.  
  167. void() ApplyMultiDamage =
  168. {
  169.     if (!multi_ent)
  170.         return;
  171.     T_Damage (multi_ent, self, self, multi_damage);
  172. };
  173.  
  174. void(entity hit, float damage) AddMultiDamage =
  175. {
  176.     if (!hit)
  177.         return;
  178.     
  179.     if (hit != multi_ent)
  180.     {
  181.         ApplyMultiDamage ();
  182.         multi_damage = damage;
  183.         multi_ent = hit;
  184.     }
  185.     else
  186.         multi_damage = multi_damage + damage;
  187. };
  188.  
  189. /*
  190. ==============================================================================
  191.  
  192. BULLETS
  193.  
  194. ==============================================================================
  195. */
  196.  
  197. /*
  198. ================
  199. TraceAttack
  200. ================
  201. */
  202. void(float damage, vector dir) TraceAttack =
  203. {
  204.     local    vector    vel, org;
  205.     
  206.     vel = normalize(dir + v_up*crandom() + v_right*crandom());
  207.     vel = vel + 2*trace_plane_normal;
  208.     vel = vel * 200;
  209.  
  210.     org = trace_endpos - dir*4;
  211.  
  212.     if (trace_ent.takedamage)
  213.     {
  214.         SpawnBlood (org, vel*0.2, damage);
  215.         AddMultiDamage (trace_ent, damage);
  216.     }
  217.     else
  218.     {
  219.         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  220.         WriteByte (MSG_BROADCAST, TE_GUNSHOT);
  221.         WriteCoord (MSG_BROADCAST, org_x);
  222.         WriteCoord (MSG_BROADCAST, org_y);
  223.         WriteCoord (MSG_BROADCAST, org_z);
  224.     }
  225. };
  226.  
  227. /*
  228. ================
  229. FireBullets
  230.  
  231. Used by shotgun, super shotgun, and enemy soldier firing
  232. Go to the trouble of combining multiple pellets into a single damage call.
  233. ================
  234. */
  235. void(float shotcount, vector dir, vector spread) FireBullets =
  236. {
  237.     local    vector direction;
  238.     local    vector    src;
  239.     
  240.     makevectors(self.v_angle);
  241.  
  242.     src = self.origin + v_forward*10;
  243.     src_z = self.absmin_z + self.size_z * 0.7;
  244.  
  245.     ClearMultiDamage ();
  246.     while (shotcount > 0)
  247.     {
  248.         direction = dir + crandom()*spread_x*v_right + crandom()*spread_y*v_up;
  249.  
  250.         traceline (src, src + direction*2048, FALSE, self);
  251.         if (trace_fraction != 1.0)
  252.             TraceAttack (4, direction);
  253.  
  254.         shotcount = shotcount - 1;
  255.     }
  256.     ApplyMultiDamage ();
  257. };
  258.  
  259. /*
  260. ================
  261. W_FireShotgun
  262. ================
  263. */
  264. void() W_FireShotgun =
  265. {
  266.     local vector dir;
  267.  
  268.     sound (self, CHAN_WEAPON, "weapons/guncock.wav", 1, ATTN_NORM);    
  269.  
  270.     self.punchangle_x = -2;
  271.     
  272.     self.currentammo = self.ammo_shells = self.ammo_shells - 1;
  273.     dir = aim (self, 100000);
  274.     FireBullets (14, dir, '0.03 0.03 0');
  275. };
  276.  
  277.  
  278. /*
  279. ================
  280. W_FireSuperShotgun
  281. ================
  282. */
  283. void() W_FireSuperShotgun =
  284. {
  285.     local vector dir;
  286.  
  287.     if (self.currentammo == 1)
  288.     {
  289.         W_FireShotgun ();
  290.         return;
  291.     }
  292.         
  293.     sound (self ,CHAN_WEAPON, "weapons/shotgn2.wav", 1, ATTN_NORM);    
  294.  
  295.     self.punchangle_x = -4;
  296.     
  297.     self.currentammo = self.ammo_shells = self.ammo_shells - 2;
  298.     dir = aim (self, 100000);
  299.     FireBullets (32, dir, '0.16 0.1 0');
  300. };
  301.  
  302.  
  303. /*
  304. ==============================================================================
  305.  
  306. ROCKETS
  307.  
  308. ==============================================================================
  309. */
  310.  
  311. void()    s_explode1    =    [0,        s_explode2] {};
  312. void()    s_explode2    =    [1,        s_explode3] {};
  313. void()    s_explode3    =    [2,        s_explode4] {};
  314. void()    s_explode4    =    [3,        s_explode5] {};
  315. void()    s_explode5    =    [4,        s_explode6] {};
  316. void()    s_explode6    =    [5,        SUB_Remove] {};
  317.  
  318. void() BecomeExplosion =
  319. {
  320.     self.movetype = MOVETYPE_NONE;
  321.     self.velocity = '0 0 0';
  322.     self.touch = SUB_Null;
  323.     setmodel (self, "progs/s_explod.spr");
  324.     self.solid = SOLID_NOT;
  325.     s_explode1 ();
  326. };
  327.  
  328. void() T_MissileTouch =
  329. {
  330.     local float    damg;
  331.  
  332.     if (other == self.owner)
  333.         return;        // don't explode on owner
  334.  
  335.     if (pointcontents(self.origin) == CONTENT_SKY)
  336.     {
  337.         remove(self);
  338.         return;
  339.     }
  340.  
  341.     damg = 100 + random()*20;
  342.     
  343.     if (other.health)
  344.     {
  345.         if (other.classname == "monster_shambler")
  346.             damg = damg * 0.5;    // mostly immune
  347.         T_Damage (other, self, self.owner, damg );
  348.     }
  349.  
  350.     // don't do radius damage to the other, because all the damage
  351.     // was done in the impact
  352.     T_RadiusDamage (self, self.owner, 120, other);
  353.  
  354. //    sound (self, CHAN_WEAPON, "weapons/r_exp3.wav", 1, ATTN_NORM);
  355.     self.origin = self.origin - 8*normalize(self.velocity);
  356.  
  357.     WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  358.     WriteByte (MSG_BROADCAST, TE_EXPLOSION);
  359.     WriteCoord (MSG_BROADCAST, self.origin_x);
  360.     WriteCoord (MSG_BROADCAST, self.origin_y);
  361.     WriteCoord (MSG_BROADCAST, self.origin_z);
  362.  
  363.     BecomeExplosion ();
  364. };
  365.  
  366.  
  367.  
  368. /*
  369. ================
  370. W_FireRocket
  371. ================
  372. */
  373. void() W_FireRocket =
  374. {
  375.     local    entity missile, mpuff;
  376.     
  377.     self.currentammo = self.ammo_rockets = self.ammo_rockets - 1;
  378.     
  379.     sound (self, CHAN_WEAPON, "weapons/sgun1.wav", 1, ATTN_NORM);
  380.  
  381.     self.punchangle_x = -2;
  382.  
  383.     missile = spawn ();
  384.     missile.owner = self;
  385.     missile.movetype = MOVETYPE_FLYMISSILE;
  386.     missile.solid = SOLID_BBOX;
  387.         
  388. // set missile speed    
  389.  
  390.     makevectors (self.v_angle);
  391.     missile.velocity = aim(self, 1000);
  392.     missile.velocity = missile.velocity * 500;
  393.     missile.angles = vectoangles(missile.velocity);
  394.     
  395.     missile.touch = T_MissileTouch;
  396.     
  397. // set missile duration
  398.     missile.nextthink = time + 10;
  399.     missile.think = SUB_Remove;
  400.  
  401.     setmodel (missile, "progs/missile.mdl");
  402.     setsize (missile, '0 0 0', '0 0 0');        
  403.     setorigin (missile, self.origin + v_forward*8 + '0 0 16');
  404. };
  405.  
  406. /*
  407. ===============================================================================
  408.  
  409. LIGHTNING
  410.  
  411. ===============================================================================
  412. */
  413.  
  414. /*
  415. =================
  416. LightningDamage
  417. =================
  418. */
  419. void(vector p1, vector p2, entity from, float damage) LightningDamage =
  420. {
  421.     local entity        e1, e2;
  422.     local vector        f;
  423.     
  424.     f = p2 - p1;
  425.     normalize (f);
  426.     f_x = 0 - f_y;
  427.     f_y = f_x;
  428.     f_z = 0;
  429.     f = f*16;
  430.  
  431.     e1 = e2 = world;
  432.  
  433.     traceline (p1, p2, FALSE, self);
  434.     if (trace_ent.takedamage)
  435.     {
  436.         particle (trace_endpos, '0 0 100', 225, damage*4);
  437.         T_Damage (trace_ent, from, from, damage);
  438.         if (self.classname == "player")
  439.         {
  440.             if (other.classname == "player")
  441.                 trace_ent.velocity_z = trace_ent.velocity_z + 400;
  442.         }
  443.     }
  444.     e1 = trace_ent;
  445.  
  446.     traceline (p1 + f, p2 + f, FALSE, self);
  447.     if (trace_ent != e1 && trace_ent.takedamage)
  448.     {
  449.         particle (trace_endpos, '0 0 100', 225, damage*4);
  450.         T_Damage (trace_ent, from, from, damage);
  451.     }
  452.     e2 = trace_ent;
  453.  
  454.     traceline (p1 - f, p2 - f, FALSE, self);
  455.     if (trace_ent != e1 && trace_ent != e2 && trace_ent.takedamage)
  456.     {
  457.         particle (trace_endpos, '0 0 100', 225, damage*4);
  458.         T_Damage (trace_ent, from, from, damage);
  459.     }
  460. };
  461.  
  462.  
  463. void() W_FireLightning =
  464. {
  465.     local    vector        org;
  466.  
  467.     if (self.ammo_cells < 1)
  468.     {
  469.         self.weapon = W_BestWeapon ();
  470.         W_SetCurrentAmmo ();
  471.         return;
  472.     }
  473.  
  474. // explode if under water
  475.     if (self.waterlevel > 1)
  476.     {
  477.         T_RadiusDamage (self, self, 35*self.ammo_cells, world);
  478.         self.ammo_cells = 0;
  479.         W_SetCurrentAmmo ();
  480.         return;
  481.     }
  482.  
  483.     if (self.t_width < time)
  484.     {
  485.         sound (self, CHAN_WEAPON, "weapons/lhit.wav", 1, ATTN_NORM);
  486.         self.t_width = time + 0.6;
  487.     }
  488.     self.punchangle_x = -2;
  489.  
  490.     self.currentammo = self.ammo_cells = self.ammo_cells - 1;
  491.  
  492.     org = self.origin + '0 0 16';
  493.     
  494.     traceline (org, org + v_forward*600, TRUE, self);
  495.  
  496.     WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  497.     WriteByte (MSG_BROADCAST, TE_LIGHTNING2);
  498.     WriteEntity (MSG_BROADCAST, self);
  499.     WriteCoord (MSG_BROADCAST, org_x);
  500.     WriteCoord (MSG_BROADCAST, org_y);
  501.     WriteCoord (MSG_BROADCAST, org_z);
  502.     WriteCoord (MSG_BROADCAST, trace_endpos_x);
  503.     WriteCoord (MSG_BROADCAST, trace_endpos_y);
  504.     WriteCoord (MSG_BROADCAST, trace_endpos_z);
  505.  
  506.     LightningDamage (self.origin, trace_endpos + v_forward*4, self, 30);
  507. };
  508.  
  509.  
  510. //=============================================================================
  511.  
  512.  
  513. void() GrenadeExplode =
  514. {
  515.     T_RadiusDamage (self, self.owner, 120, world);
  516.  
  517.     WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  518.     WriteByte (MSG_BROADCAST, TE_EXPLOSION);
  519.     WriteCoord (MSG_BROADCAST, self.origin_x);
  520.     WriteCoord (MSG_BROADCAST, self.origin_y);
  521.     WriteCoord (MSG_BROADCAST, self.origin_z);
  522.  
  523.     BecomeExplosion ();
  524. };
  525.  
  526. void() GrenadeTouch =
  527. {
  528.     if (other == self.owner)
  529.         return;        // don't explode on owner
  530.     if (other.takedamage == DAMAGE_AIM)
  531.     {
  532.         GrenadeExplode();
  533.         return;
  534.     }
  535.     sound (self, CHAN_WEAPON, "weapons/bounce.wav", 1, ATTN_NORM);    // bounce sound
  536.     if (self.velocity == '0 0 0')
  537.         self.avelocity = '0 0 0';
  538. };
  539.  
  540. /*
  541. ================
  542. W_FireGrenade
  543. ================
  544. */
  545. void() W_FireGrenade =
  546. {
  547.     local    entity missile, mpuff;
  548.     
  549.     self.currentammo = self.ammo_rockets = self.ammo_rockets - 1;
  550.     
  551.     sound (self, CHAN_WEAPON, "weapons/grenade.wav", 1, ATTN_NORM);
  552.  
  553.     self.punchangle_x = -2;
  554.  
  555.     missile = spawn ();
  556.     missile.owner = self;
  557.     missile.movetype = MOVETYPE_BOUNCE;
  558.     missile.solid = SOLID_BBOX;
  559.     missile.classname = "grenade";
  560.         
  561. // set missile speed    
  562.  
  563.     makevectors (self.v_angle);
  564.  
  565.     if (self.v_angle_x)
  566.         missile.velocity = v_forward*600 + v_up * 200 + crandom()*v_right*10 + crandom()*v_up*10;
  567.     else
  568.     {
  569.         missile.velocity = aim(self, 10000);
  570.         missile.velocity = missile.velocity * 600;
  571.         missile.velocity_z = 200;
  572.     }
  573.  
  574.     missile.avelocity = '300 300 300';
  575.  
  576.     missile.angles = vectoangles(missile.velocity);
  577.     
  578.     missile.touch = GrenadeTouch;
  579.     
  580. // set missile duration
  581.     missile.nextthink = time + 2.5;
  582.     missile.think = GrenadeExplode;
  583.  
  584.     setmodel (missile, "progs/grenade.mdl");
  585.     setsize (missile, '0 0 0', '0 0 0');        
  586.     setorigin (missile, self.origin);
  587. };
  588.  
  589.  
  590. //=============================================================================
  591.  
  592. void() spike_touch;
  593. void() superspike_touch;
  594.  
  595.  
  596. /*
  597. ===============
  598. launch_spike
  599.  
  600. Used for both the player and the ogre
  601. ===============
  602. */
  603. void(vector org, vector dir) launch_spike =
  604. {
  605.     newmis = spawn ();
  606.     newmis.owner = self;
  607.     newmis.movetype = MOVETYPE_FLYMISSILE;
  608.     newmis.solid = SOLID_BBOX;
  609.  
  610.     newmis.angles = vectoangles(dir);
  611.     
  612.     newmis.touch = spike_touch;
  613.     newmis.classname = "spike";
  614.     newmis.think = SUB_Remove;
  615.     newmis.nextthink = time + 6;
  616.     setmodel (newmis, "progs/spike.mdl");
  617.     setsize (newmis, VEC_ORIGIN, VEC_ORIGIN);        
  618.     setorigin (newmis, org);
  619.  
  620.     newmis.velocity = dir * 1000;
  621. };
  622.  
  623. void() W_FireSuperSpikes =
  624. {
  625.     local vector    dir;
  626.     local entity    old;
  627.     
  628.     sound (self, CHAN_WEAPON, "weapons/spike2.wav", 1, ATTN_NORM);
  629.     self.attack_finished = time + 0.2;
  630.     self.currentammo = self.ammo_nails = self.ammo_nails - 2;
  631.     dir = aim (self, 1000);
  632.     launch_spike (self.origin + '0 0 16', dir);
  633.     newmis.touch = superspike_touch;
  634.     setmodel (newmis, "progs/s_spike.mdl");
  635.     setsize (newmis, VEC_ORIGIN, VEC_ORIGIN);        
  636.     self.punchangle_x = -2;
  637. };
  638.  
  639. void(float ox) W_FireSpikes =
  640. {
  641.     local vector    dir;
  642.     local entity    old;
  643.     
  644.     makevectors (self.v_angle);
  645.     
  646.     if (self.ammo_nails >= 2 && self.weapon == IT_SUPER_NAILGUN)
  647.     {
  648.         W_FireSuperSpikes ();
  649.         return;
  650.     }
  651.  
  652.     if (self.ammo_nails < 1)
  653.     {
  654.         self.weapon = W_BestWeapon ();
  655.         W_SetCurrentAmmo ();
  656.         return;
  657.     }
  658.  
  659.     sound (self, CHAN_WEAPON, "weapons/rocket1i.wav", 1, ATTN_NORM);
  660.     self.attack_finished = time + 0.2;
  661.     self.currentammo = self.ammo_nails = self.ammo_nails - 1;
  662.     dir = aim (self, 1000);
  663.     launch_spike (self.origin + '0 0 16' + v_right*ox, dir);
  664.  
  665.     self.punchangle_x = -2;
  666. };
  667.  
  668.  
  669.  
  670. .float hit_z;
  671. void() spike_touch =
  672. {
  673. local float rand;
  674.     if (other == self.owner)
  675.         return;
  676.  
  677.     if (other.solid == SOLID_TRIGGER)
  678.         return;    // trigger field, do nothing
  679.  
  680.     if (pointcontents(self.origin) == CONTENT_SKY)
  681.     {
  682.         remove(self);
  683.         return;
  684.     }
  685.     
  686. // hit something that bleeds
  687.     if (other.takedamage)
  688.     {
  689.         spawn_touchblood (9);
  690.         T_Damage (other, self, self.owner, 9);
  691.     }
  692.     else
  693.     {
  694.         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  695.         
  696.         if (self.classname == "wizspike")
  697.             WriteByte (MSG_BROADCAST, TE_WIZSPIKE);
  698.         else if (self.classname == "knightspike")
  699.             WriteByte (MSG_BROADCAST, TE_KNIGHTSPIKE);
  700.         else
  701.             WriteByte (MSG_BROADCAST, TE_SPIKE);
  702.         WriteCoord (MSG_BROADCAST, self.origin_x);
  703.         WriteCoord (MSG_BROADCAST, self.origin_y);
  704.         WriteCoord (MSG_BROADCAST, self.origin_z);
  705.     }
  706.  
  707.     remove(self);
  708.  
  709. };
  710.  
  711. void() superspike_touch =
  712. {
  713. local float rand;
  714.     if (other == self.owner)
  715.         return;
  716.  
  717.     if (other.solid == SOLID_TRIGGER)
  718.         return;    // trigger field, do nothing
  719.  
  720.     if (pointcontents(self.origin) == CONTENT_SKY)
  721.     {
  722.         remove(self);
  723.         return;
  724.     }
  725.     
  726. // hit something that bleeds
  727.     if (other.takedamage)
  728.     {
  729.         spawn_touchblood (18);
  730.         T_Damage (other, self, self.owner, 18);
  731.     }
  732.     else
  733.     {
  734.         WriteByte (MSG_BROADCAST, SVC_TEMPENTITY);
  735.         WriteByte (MSG_BROADCAST, TE_SUPERSPIKE);
  736.         WriteCoord (MSG_BROADCAST, self.origin_x);
  737.         WriteCoord (MSG_BROADCAST, self.origin_y);
  738.         WriteCoord (MSG_BROADCAST, self.origin_z);
  739.     }
  740.  
  741.     remove(self);
  742.  
  743. };
  744.  
  745.  
  746. /*
  747. ===============================================================================
  748.  
  749. PLAYER WEAPON USE
  750.  
  751. ===============================================================================
  752. */
  753.  
  754. void() W_SetCurrentAmmo =
  755. {
  756.     player_run ();        // get out of any weapon firing states
  757.  
  758.     self.items = self.items - ( self.items & (IT_SHELLS | IT_NAILS | IT_ROCKETS | IT_CELLS) );
  759.     
  760.     if (self.weapon == IT_AXE)
  761.     {
  762.         self.currentammo = 0;
  763.         self.weaponmodel = "progs/v_axe.mdl";
  764.         self.weaponframe = 0;
  765.     }
  766.     else if (self.weapon == IT_SHOTGUN)
  767.     {
  768.         self.currentammo = self.ammo_shells;
  769.         self.weaponmodel = "progs/v_shot.mdl";
  770.         self.weaponframe = 0;
  771.         self.items = self.items | IT_SHELLS;
  772.     }
  773.     else if (self.weapon == IT_SUPER_SHOTGUN)
  774.     {
  775.         self.currentammo = self.ammo_shells;
  776.         self.weaponmodel = "progs/v_shot2.mdl";
  777.         self.weaponframe = 0;
  778.         self.items = self.items | IT_SHELLS;
  779.     }
  780.     else if (self.weapon == IT_NAILGUN)
  781.     {
  782.         self.currentammo = self.ammo_nails;
  783.         self.weaponmodel = "progs/v_nail.mdl";
  784.         self.weaponframe = 0;
  785.         self.items = self.items | IT_NAILS;
  786.     }
  787.     else if (self.weapon == IT_SUPER_NAILGUN)
  788.     {
  789.         self.currentammo = self.ammo_nails;
  790.         self.weaponmodel = "progs/v_nail2.mdl";
  791.         self.weaponframe = 0;
  792.         self.items = self.items | IT_NAILS;
  793.     }
  794.     else if (self.weapon == IT_GRENADE_LAUNCHER)
  795.     {
  796.         self.currentammo = self.ammo_rockets;
  797.         self.weaponmodel = "progs/v_rock.mdl";
  798.         self.weaponframe = 0;
  799.         self.items = self.items | IT_ROCKETS;
  800.     }
  801.     else if (self.weapon == IT_ROCKET_LAUNCHER)
  802.     {
  803.         self.currentammo = self.ammo_rockets;
  804.         self.weaponmodel = "progs/v_rock2.mdl";
  805.         self.weaponframe = 0;
  806.         self.items = self.items | IT_ROCKETS;
  807.     }
  808.     else if (self.weapon == IT_LIGHTNING)
  809.     {
  810.         self.currentammo = self.ammo_cells;
  811.         self.weaponmodel = "progs/v_light.mdl";
  812.         self.weaponframe = 0;
  813.         self.items = self.items | IT_CELLS;
  814.     }
  815.     else
  816.     {
  817.         self.currentammo = 0;
  818.         self.weaponmodel = "";
  819.         self.weaponframe = 0;
  820.     }
  821. };
  822.  
  823. float() W_BestWeapon =
  824. {
  825.     local    float    it;
  826.     
  827.     it = self.items;
  828.  
  829.     if(self.ammo_cells >= 1 && (it & IT_LIGHTNING) )
  830.         return IT_LIGHTNING;
  831.     else if(self.ammo_nails >= 2 && (it & IT_SUPER_NAILGUN) )
  832.         return IT_SUPER_NAILGUN;
  833.     else if(self.ammo_shells >= 2 && (it & IT_SUPER_SHOTGUN) )
  834.         return IT_SUPER_SHOTGUN;
  835.     else if(self.ammo_nails >= 1 && (it & IT_NAILGUN) )
  836.         return IT_NAILGUN;
  837.     else if(self.ammo_shells >= 1 && (it & IT_SHOTGUN) )
  838.         return IT_SHOTGUN;
  839.         
  840. /*
  841.     if(self.ammo_rockets >= 1 && (it & IT_ROCKET_LAUNCHER) )
  842.         return IT_ROCKET_LAUNCHER;
  843.     else if(self.ammo_rockets >= 1 && (it & IT_GRENADE_LAUNCHER) )
  844.         return IT_GRENADE_LAUNCHER;
  845.  
  846. */
  847.  
  848.     return IT_AXE;
  849. };
  850.  
  851. float() W_CheckNoAmmo =
  852. {
  853.     if (self.currentammo > 0)
  854.         return TRUE;
  855.  
  856.     if (self.weapon == IT_AXE)
  857.         return TRUE;
  858.     
  859.     self.weapon = W_BestWeapon ();
  860.  
  861.     W_SetCurrentAmmo ();
  862.     
  863. // drop the weapon down
  864.     return FALSE;
  865. };
  866.  
  867. /*
  868. ============
  869. W_Attack
  870.  
  871. An attack impulse can be triggered now
  872. ============
  873. */
  874. void()    player_axe1;
  875. void()    player_axeb1;
  876. void()    player_axec1;
  877. void()    player_axed1;
  878. void()    player_shot1;
  879. void()    player_nail1;
  880. void()    player_light1;
  881. void()    player_rocket1;
  882.  
  883. void() W_Attack =
  884. {
  885.     local    float    r;
  886.  
  887.     if (!W_CheckNoAmmo ())
  888.         return;
  889.  
  890.     makevectors    (self.v_angle);            // calculate forward angle for velocity
  891.     self.show_hostile = time + 1;    // wake monsters up
  892.  
  893.     if (self.weapon == IT_AXE)
  894.     {
  895.         sound (self, CHAN_WEAPON, "weapons/ax1.wav", 1, ATTN_NORM);
  896.         r = random();
  897.         if (r < 0.25)
  898.             player_axe1 ();
  899.         else if (r<0.5)
  900.             player_axeb1 ();
  901.         else if (r<0.75)
  902.             player_axec1 ();
  903.         else
  904.             player_axed1 ();
  905.         self.attack_finished = time + 0.5;
  906.     }
  907.     else if (self.weapon == IT_SHOTGUN)
  908.     {
  909.         player_shot1 ();
  910.         W_FireShotgun ();
  911.         self.attack_finished = time + 0.5;
  912.     }
  913.     else if (self.weapon == IT_SUPER_SHOTGUN)
  914.     {
  915.         player_shot1 ();
  916.         W_FireSuperShotgun ();
  917.         self.attack_finished = time + 0.9;
  918.     }
  919.     else if (self.weapon == IT_NAILGUN)
  920.     {
  921.         player_nail1 ();
  922.     }
  923.     else if (self.weapon == IT_SUPER_NAILGUN)
  924.     {
  925.         player_nail1 ();
  926.     }
  927.     else if (self.weapon == IT_GRENADE_LAUNCHER)
  928.     {
  929.         player_rocket1();
  930.         W_FireGrenade();
  931.         self.attack_finished = time + 0.6;
  932.     }
  933.     else if (self.weapon == IT_ROCKET_LAUNCHER)
  934.     {
  935.         player_rocket1();
  936.         W_FireRocket();
  937.         self.attack_finished = time + 0.8;
  938.     }
  939.     else if (self.weapon == IT_LIGHTNING)
  940.     {
  941.         player_light1();
  942.         self.attack_finished = time + 0.1;
  943.         sound (self, CHAN_AUTO, "weapons/lstart.wav", 1, ATTN_NORM);
  944.     }
  945. };
  946.  
  947. /*
  948. ============
  949. W_ChangeWeapon
  950.  
  951. ============
  952. */
  953. void() W_ChangeWeapon =
  954. {
  955.     local    float    it, am, fl;
  956.     
  957.     it = self.items;
  958.     am = 0;
  959.     
  960.     if (self.impulse == 1)
  961.     {
  962.         fl = IT_AXE;
  963.     }
  964.     else if (self.impulse == 2)
  965.     {
  966.         fl = IT_SHOTGUN;
  967.         if (self.ammo_shells < 1)
  968.             am = 1;
  969.     }
  970.     else if (self.impulse == 3)
  971.     {
  972.         fl = IT_SUPER_SHOTGUN;
  973.         if (self.ammo_shells < 2)
  974.             am = 1;
  975.     }        
  976.     else if (self.impulse == 4)
  977.     {
  978.         fl = IT_NAILGUN;
  979.         if (self.ammo_nails < 1)
  980.             am = 1;
  981.     }
  982.     else if (self.impulse == 5)
  983.     {
  984.         fl = IT_SUPER_NAILGUN;
  985.         if (self.ammo_nails < 2)
  986.             am = 1;
  987.     }
  988.     else if (self.impulse == 6)
  989.     {
  990.         fl = IT_GRENADE_LAUNCHER;
  991.         if (self.ammo_rockets < 1)
  992.             am = 1;
  993.     }
  994.     else if (self.impulse == 7)
  995.     {
  996.         fl = IT_ROCKET_LAUNCHER;
  997.         if (self.ammo_rockets < 1)
  998.             am = 1;
  999.     }
  1000.     else if (self.impulse == 8)
  1001.     {
  1002.         fl = IT_LIGHTNING;
  1003.         if (self.ammo_cells < 1)
  1004.             am = 1;
  1005.     }
  1006.  
  1007.     self.impulse = 0;
  1008.     
  1009.     if (!(self.items & fl))
  1010.     {    // don't have the weapon or the ammo
  1011.         sprint (self, "no weapon.\n");
  1012.         return;
  1013.     }
  1014.     
  1015.     if (am)
  1016.     {    // don't have the ammo
  1017.         sprint (self, "not enough ammo.\n");
  1018.         return;
  1019.     }
  1020.  
  1021. //
  1022. // set weapon, set ammo
  1023. //
  1024.     self.weapon = fl;        
  1025.     W_SetCurrentAmmo ();
  1026. };
  1027.  
  1028. /*
  1029. ============
  1030. CheatCommand
  1031. ============
  1032. */
  1033. void() CheatCommand =
  1034. {
  1035.     if (deathmatch || coop)
  1036.         return;
  1037.  
  1038.     self.ammo_rockets = 100;
  1039.     self.ammo_nails = 200;
  1040.     self.ammo_shells = 100;
  1041.     self.items = self.items | 
  1042.         IT_AXE |
  1043.         IT_SHOTGUN |
  1044.         IT_SUPER_SHOTGUN |
  1045.         IT_NAILGUN |
  1046.         IT_SUPER_NAILGUN |
  1047.         IT_GRENADE_LAUNCHER |
  1048.         IT_ROCKET_LAUNCHER |
  1049.         IT_KEY1 | IT_KEY2;
  1050.  
  1051.     self.ammo_cells = 200;
  1052.     self.items = self.items | IT_LIGHTNING;
  1053.  
  1054.     self.weapon = IT_ROCKET_LAUNCHER;
  1055.     self.impulse = 0;
  1056.     W_SetCurrentAmmo ();
  1057. };
  1058.  
  1059. /*
  1060. ============
  1061. CycleWeaponCommand
  1062.  
  1063. Go to the next weapon with ammo
  1064. ============
  1065. */
  1066. void() CycleWeaponCommand =
  1067. {
  1068.     local    float    it, am;
  1069.     
  1070.     it = self.items;
  1071.     self.impulse = 0;
  1072.     
  1073.     while (1)
  1074.     {
  1075.         am = 0;
  1076.  
  1077.         if (self.weapon == IT_LIGHTNING)
  1078.         {
  1079.             self.weapon = IT_AXE;
  1080.         }
  1081.         else if (self.weapon == IT_AXE)
  1082.         {
  1083.             self.weapon = IT_SHOTGUN;
  1084.             if (self.ammo_shells < 1)
  1085.                 am = 1;
  1086.         }
  1087.         else if (self.weapon == IT_SHOTGUN)
  1088.         {
  1089.             self.weapon = IT_SUPER_SHOTGUN;
  1090.             if (self.ammo_shells < 2)
  1091.                 am = 1;
  1092.         }        
  1093.         else if (self.weapon == IT_SUPER_SHOTGUN)
  1094.         {
  1095.             self.weapon = IT_NAILGUN;
  1096.             if (self.ammo_nails < 1)
  1097.                 am = 1;
  1098.         }
  1099.         else if (self.weapon == IT_NAILGUN)
  1100.         {
  1101.             self.weapon = IT_SUPER_NAILGUN;
  1102.             if (self.ammo_nails < 2)
  1103.                 am = 1;
  1104.         }
  1105.         else if (self.weapon == IT_SUPER_NAILGUN)
  1106.         {
  1107.             self.weapon = IT_GRENADE_LAUNCHER;
  1108.             if (self.ammo_rockets < 1)
  1109.                 am = 1;
  1110.         }
  1111.         else if (self.weapon == IT_GRENADE_LAUNCHER)
  1112.         {
  1113.             self.weapon = IT_ROCKET_LAUNCHER;
  1114.             if (self.ammo_rockets < 1)
  1115.                 am = 1;
  1116.         }
  1117.         else if (self.weapon == IT_ROCKET_LAUNCHER)
  1118.         {
  1119.             self.weapon = IT_LIGHTNING;
  1120.             if (self.ammo_cells < 1)
  1121.                 am = 1;
  1122.         }
  1123.     
  1124.         if ( (self.items & self.weapon) && am == 0)
  1125.         {
  1126.             W_SetCurrentAmmo ();
  1127.             return;
  1128.         }
  1129.     }
  1130.  
  1131. };
  1132.  
  1133. /*
  1134. ============
  1135. ServerflagsCommand
  1136.  
  1137. Just for development
  1138. ============
  1139. */
  1140. void() ServerflagsCommand =
  1141. {
  1142.     serverflags = serverflags * 2 + 1;
  1143. };
  1144.  
  1145. void() QuadCheat =
  1146. {
  1147.     if (deathmatch || coop)
  1148.         return;
  1149.     self.super_time = 1;
  1150.     self.super_damage_finished = time + 30;
  1151.     self.items = self.items | IT_QUAD;
  1152.     dprint ("quad cheat\n");
  1153. };
  1154.  
  1155. /*
  1156. ============
  1157. ImpulseCommands
  1158.  
  1159. ============
  1160. */
  1161. void() ImpulseCommands =
  1162. {
  1163.     if (self.impulse >= 1 && self.impulse <= 8)
  1164.         W_ChangeWeapon ();
  1165.  
  1166.     if (self.impulse == 9)
  1167.         CheatCommand ();
  1168.     if (self.impulse == 10)
  1169.         CycleWeaponCommand ();
  1170.     if (self.impulse == 11)
  1171.         ServerflagsCommand ();
  1172.  
  1173.     if (self.impulse == 255)
  1174.         QuadCheat ();
  1175.         
  1176.     self.impulse = 0;
  1177. };
  1178.  
  1179. /*
  1180. ============
  1181. W_WeaponFrame
  1182.  
  1183. Called every frame so impulse events can be handled as well as possible
  1184. ============
  1185. */
  1186. void() W_WeaponFrame =
  1187. {
  1188.     if (time < self.attack_finished)
  1189.         return;
  1190.  
  1191.     ImpulseCommands ();
  1192.     
  1193. // check for attack
  1194.     if (self.button0)
  1195.     {
  1196.         SuperDamageSound ();
  1197.         W_Attack ();
  1198.     }
  1199. };
  1200.  
  1201. /*
  1202. ========
  1203. SuperDamageSound
  1204.  
  1205. Plays sound if needed
  1206. ========
  1207. */
  1208. void() SuperDamageSound =
  1209. {
  1210.     if (self.super_damage_finished > time)
  1211.     {
  1212.         if (self.super_sound < time)
  1213.         {
  1214.             self.super_sound = time + 1;
  1215.             sound (self, CHAN_BODY, "items/damage3.wav", 1, ATTN_NORM);
  1216.         }
  1217.     }
  1218.     return;
  1219. };
  1220.  
  1221.  
  1222.